cmake_minimum_required(VERSION 3.7...3.22 FATAL_ERROR)
project(Starter VERSION 7.9 LANGUAGES CXX)

# Ensure we have access to MSVC_RUNTIME_LIBRARY property for Windows builds
if (WIN32 AND NOT CMAKE_VERSION VERSION_GREATER_EQUAL 3.15)
    message(FATAL_ERROR "cmake ${CMAKE_VERSION} is not supported for Windows builds")
endif()

if (CMAKE_VERSION VERSION_GREATER_EQUAL 3.11)
    get_property(IS_MULTI_CONFIG GLOBAL PROPERTY GENERATOR_IS_MULTI_CONFIG)
elseif(CMAKE_CONFIGURATION_TYPES)
    set(IS_MULTI_CONFIG YES)
else()
    set(IS_MULTI_CONFIG NO)
endif()

if(NOT CMAKE_BUILD_TYPE AND NOT IS_MULTI_CONFIG)
    message(STATUS "No build type specified - default is DEBUG")
    set(CMAKE_BUILD_TYPE DEBUG)
endif()

list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
find_package(Tango REQUIRED)

set(SOURCES CheckProcessUtil.cpp
            ClassFactory.cpp
            main.cpp
            PingThread.cpp
            Starter.cpp
            StarterClass.cpp
            StarterService.cpp
            StarterStateMachine.cpp
            StarterUtil.cpp
            StartProcessThread.cpp)

set(HEADER CheckProcessUtil.h
           Logging.h
           PingThread.h
           Starter.h
           StarterClass.h
           StarterService.h
           StarterUtil.h)

add_executable(Starter ${SOURCES} ${HEADER})
target_link_libraries(Starter PRIVATE Tango::Tango)

if (WIN32 AND (Tango_IS_STATIC OR Tango_FORCE_STATIC))
    set_target_properties(${PROJECT_NAME} PROPERTIES
        MSVC_RUNTIME_LIBRARY "MultiThreaded$<$<CONFIG:Debug>:Debug>"
    )
endif()

if (MSVC)
    # Starter requires WIN32 UNICODE string support see
    # https://learn.microsoft.com/en-us/cpp/text/unicode-programming-summary?view=msvc-170
    target_compile_options(Starter PUBLIC /W3 /D_UNICODE)
else()
    target_compile_options(Starter PUBLIC -Wall -Wextra -D_FORTIFY_SOURCE=2 -O1)

    if(NOT (CMAKE_CXX_COMPILER_ID STREQUAL "AppleClang" OR CMAKE_CXX_COMPILER_ID STREQUAL "Clang"))
        target_compile_options(Starter PUBLIC -fpie)
        set_target_properties(Starter PROPERTIES LINK_FLAGS "-Wl,-z,now -pie")
    else()
        set_target_properties(Starter PROPERTIES LINK_FLAGS "-bind_at_load")
    endif()
endif()

install(TARGETS Starter
        RUNTIME DESTINATION "${CMAKE_INSTALL_FULL_BINDIR}")
